*****************************************
*                                       *
*     Bubble t2 screen saver            *
*                                       *
*                                       *
*                                       *
*                                       *
*                                       *
*                                       *
*                                       *
*****************************************

	case on
	mcopy b.mac


_d	gequ 1
Temp	gequ 3
_rtlb	gequ 7
Data2	gequ 11
Data1	gequ 15
Message	gequ 19
Result	gequ 21


rT2ModuleWord	gequ $1002


Bubbles	START

	using BData

	phb
	phk
	plb
	pha		;;space for Temp
	pha
	phd
	tsc
	tcd

	pha
	_MMStartUp
	pla
	sta MyID

	lda <Message
	cmp #7
	bcs exit	make sure it's valid...

	asl a		*2
	tax
	jsr (Table,x)

exit	lda <_rtlb
	sta <Data1+2
	lda <_rtlb+2
	sta <Message
	
	pld
	tsc
	clc
	adc #14
	tcs
	plb
	rtl

Table	anop
	dc i2'Make'
	dc i2'Save'
	dc i2'Blank'
	dc i2'LoadSetup'
	dc i2'UnloadSetup'
	dc i2'Kill'
	dc i2'Hit'
	end

Blank	START
	using BData


	pha
	pha
	_GetTick
	_SetRandSeed

;;setup the palette

	lda #0
	ldx #2
	stz ColorTable		;;black
pal	clc
	adc ColorValue
	sta ColorTable,X
	inx
	inx
	cpx #31
	bcc pal

	~SetColorTable #0,#ColorTable

	~SetPenMode #0

clr	anop
	stz Temp
	~ClearScreen #0

rloop1	anop	
	pha
	_Random
	pla
	and #$ff
	cmp #201
	bcs rloop1

	sta Rect_top
	sta Rect_bottom

rloop2	pha
	_Random
	pla
	and #$1ff
	cmp #321
	bcs rloop2
	sta Rect_left
	sta Rect_right

	pha	
	_Random
	pla
	and #1
	sta Size

	lda #14
	sta Color

dloop	anop

	lda [<Data1]
	bne quit

	lda Color
	pha
	_SetSolidPenPat

	jsr Draw

	lda Size
	beq foo
	jsr Draw
foo	anop
	dec Color
	bne dloop
	lda <Temp
	inc a
	sta <Temp	;;counter for # of pics
	cmp #30
	bcc rloop1
	bra clr		;;and again

quit	anop
	stz <Result
	stz <Result+2
	rts


Draw	anop

	~InsetRect #Rect,#-1,#-1	;;grow the rectangle

	lda Type
	beq Oval
	~FrameRect #Rect
	rts
Oval	~FrameOval #Rect
	rts


	END

Kill	START
UnloadSetup ENTRY
	rts
	END


LoadSetup START
	
	using BData

rID	equ Data2
Handle	equ Temp
Ptr	equ Data1


	pha
	pha
	~RMFindNamedResource #rT2ModuleWord,#ConfigName,#FileID
	plax <rID

	pha
	pha
	~LoadResource #rT2ModuleWord,<rID
	plax <Handle
	lda #1		;;default value
	bcs got_it

	~Hlock <Handle
	ldy #2
	lda [<Handle]
	sta <Ptr
	lda [<Handle],y
	sta <Ptr+2
	lda [<Ptr]
	pha	;;save

	~ReleaseResource #3,#rT2ModuleWord,<rID
	
	pla	;;restore

got_it	anop
	bit #$f000
	beq color
	ldx #1
	stx Type

color	anop	
	and #$0fff
	sta ColorValue
	rts
	END


Save	START

	using BData

rID	equ Data2
Handle	equ Temp
Ptr	equ Data1


	pha
	_GetCurResourceFile

	~SetCurResourceFile SetUpFileNo


	pha
	
	pha
	pha
	~GetCtlHandleFromID #0,#3	;;square
	_GetCtlValue
	pla
	sta Type

	pha
	
	pha
	pha
	~GetCtlHandleFromID #0,#1	;;menu
	_GetCtlValue
	pla
	sta ColorValue



	pha
	pha
	~RMFindNamedResource #rT2ModuleWord,#ConfigName,#FileID
	plax <rID
	bcs add_it

	~RMSetResourceName #rT2ModuleWord,<rID,#NullString
	~RemoveResource #rT2ModuleWord,<rID

add_it	anop

	pha
	pha
	~NewHandle #2,MyID,#$c000,#0
	plax <Handle
	ldy #2
	lda [<Handle]
	sta <Ptr
	lda [<Handle],y
	sta <Ptr+2

	lda ColorValue
	ldx Type
	beq s
	ora #$8000
s	anop
	sta [<Ptr]
	
	pha
	pha
	~UniqueResourceID #0,#rT2ModuleWord
	plax <rID

	~AddResource Handle,#0,#rT2ModuleWord,<rID
	bcc name
	~DisposeHandle <Handle
	bra quit

name	anop

	~RMSetResourceName #rT2ModuleWord,<rID,#ConfigName
	~UpdateResourceFile SetUpFileNo


quit	anop
	_SetCurResourceFile		;;old # still on stack

	rts
	END

Hit	START
	stz Result
	stz <Result+2

	lda <Data2
	cmp #4
	bcs quit
	inc <Result

quit	rts
	END

Make	START

	using BData

	lda <Data2
	sta SetUpFileNo		;;save for later

	ph4 <Data1	;;save the windptr

	jsr LoadSetup

	plax <Data1	;;restore
	

	pha
	pha
	~NewControl2 <Data1,#9,#1
	pla
	pla

	lda ColorValue
	pha
	pha
	pha
	~GetCtlHandleFromID <Data1,#1	;;color menu
	_SetCtlValue


	lda Type
	pha
	pha
	pha
	~GetCtlHandleFromID <Data1,#3	;square radio
	_SetCtlValue


	lda #5		;;# of controls
	sta <Result
	rts
Make	END

BData	Data
ColorTable	anop
	dc i2'$0000'
	dc i2'$0111'
	dc i2'$0222'
	dc i2'$0333'
	dc i2'$0444'
	dc i2'$0555'
	dc i2'$0666'
	dc i2'$0777'
	dc i2'$0888'
	dc i2'$0999'
	dc i2'$0AAA'
	dc i2'$0BBB'
	dc i2'$0CCC'
	dc i2'$0DDD'
	dc i2'$0EEE'
	dc i2'$0FFF'

Size		ds 2		;;size of circle/square
Color		ds 2
Type		dc i2'0'	;;0=circle, 1=square
Rect		anop
Rect_top	ds 2
Rect_left	ds 2
Rect_bottom	ds 2
Rect_right	ds 2
MyID		ds 2
SetUpFileNo	ds 2
ColorValue	dc i2'1'
ConfigName	pstr 'Bubble Setup'
NullString	dc i2'0'
FileID		ds 2
	end